[RESOLVIDO] UPC Mudar Folder

kikofr · Dezembro 29, 2010

Bom dia.

Estou com o seguinte problema, tenho uma UPC que cria alguns campos no cadastro (ainda estou desenvolvendo)... e quando executo essa UPC, a a tela começa no folder2 ao inves do folder1.
Alguem tem idéia do por que isso esta acontecendo?

Segue abaixo o código da UPC que tenho até agora.

Código:

{utp\ut-glob.i}
/******************** Definio de Parametros **************************/
def input param           p-ind-event         as char          no-undo.
def input param           p-ind-object        as char          no-undo.
def input param           p-wgh-object        as handle        no-undo.
def input param           p-wgh-frame         as widget-handle no-undo.
def input param           p-cod-table         as char          no-undo.
def input param           p-row-table         as rowid         no-undo.

/****************** Definio de Variveis Locais **********************/
def var c-char                                as char          no-undo.

/****************** Definio de Variveis Globais **********************/
def new global shared var tx-label-0                AS WIDGET-HANDLE NO-UNDO.
def new global shared var tx-label-1                AS WIDGET-HANDLE NO-UNDO.
def new global shared var wh-num-populacao          AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtFrame2                          AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtcd-equip-res                    AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtcd-planejado                    AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtcod-docto-anexo                 AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtdt-ini-cedo                     AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtdt-ini-tarde                    AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtbtDocto                         AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtvData                           AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtvHora                           AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtcDescPlanej                     AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wghtcDescEquipe                     AS WIDGET-HANDLE NO-UNDO.
DEFINE NEW GLOBAL SHARED VARIABLE wghtcDescEquipe2  AS WIDGET-HANDLE NO-UNDO.
DEFINE NEW GLOBAL SHARED VARIABLE wghtcd-equip-res2 AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wgthTxtEquipe2                      AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wgthTxtSolicitante                  AS WIDGET-HANDLE NO-UNDO.
DEFINE VARIABLE wgthSolicitante                     AS WIDGET-HANDLE NO-UNDO.
define new global shared var adm-broker-hdl         as handle no-undo.
define new global shared var h-folder               as handle no-undo.

/*************************************** Inicializar ********************************************/

define variable c-folder        as character    no-undo.

assign c-char = entry(num-entries(p-wgh-object:file-name,"~/"), p-wgh-object:file-name,"~/").

/*output to c:\temp\upc-mi0307a.txt no-convert append.
put unformatted
    "=====================================" skip
    "p-ind-event.: " p-ind-event            skip
    "p-ind-object: " p-ind-object           skip
    "p-wgh-object: " p-wgh-object:file-name skip
    "p-wgh-frame.: " p-wgh-frame:name       skip
    "p-cod-table.: " p-cod-table            skip
    "p-row-table.: " string(p-row-table)    skip
    "=====================================" skip(1).

output close.*/

IF p-ind-event = "AFTER-DESTROY-INTERFACE" AND
   p-ind-object = "CONTAINER" AND
   p-wgh-object:FILE-NAME = "mip/mi0307a.w" AND
   p-wgh-frame:NAME = "fpage0"
   THEN DO:
   IF VALID-HANDLE(wghtcDescEquipe2) THEN DO:
       DELETE WIDGET wghtcDescEquipe2.
   END.
   IF VALID-HANDLE(wghtcd-equip-res2) THEN DO:
       DELETE WIDGET wghtcd-equip-res2.
   END.
END.

IF p-ind-event  = "AFTER-INITIALIZE" AND
   p-ind-object = "CONTAINER" AND
   p-wgh-object:FILE-NAME = "mip/mi0307a.w" AND
   p-wgh-frame:NAME = "fpage0"
   THEN DO:
    /*RUN get-link-handle IN adm-broker-hdl (INPUT p-wgh-object,
                                           INPUT "PAGE-SOURCE":U,
                                           OUTPUT c-folder).
    assign h-folder = widget-handle(c-folder) no-error.*/

    RUN upc\upc-handle.p (INPUT p-wgh-frame,
                          INPUT "fPage2",
                          OUTPUT wghtFrame2).

    IF VALID-HANDLE(wghtFrame2) THEN DO:
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "cd-equip-res",
                              OUTPUT wghtcd-equip-res).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "dt-ini-cedo",
                              OUTPUT wghtdt-ini-cedo).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "dt-ini-tarde",
                              OUTPUT wghtdt-ini-tarde).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "vData",
                              OUTPUT wghtvData).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "vHora",
                              OUTPUT wghtvHora).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "cd-equip-res",
                              OUTPUT wghtcd-equip-res).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "cd-planejado",
                              OUTPUT wghtcd-planejado).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "cDescEquipe",
                              OUTPUT wghtcDescEquipe).
        RUN upc\upc-handle.p (INPUT wghtFrame2,
                              INPUT "cDescPlanej",
                              OUTPUT wghtcDescPlanej).

        IF VALID-HANDLE(wghtcDescPlanej) THEN DO:
            ASSIGN wghtcDescPlanej:ROW = wghtcDescPlanej:ROW - 1.
                   
        END.
        IF VALID-HANDLE(wghtcd-equip-res) THEN DO:
            ASSIGN wghtcd-equip-res:ROW = wghtcd-equip-res:ROW - 1                   
                   wghtcd-equip-res:SIDE-LABEL-HANDLE:ROW = wghtcd-equip-res:ROW
                   wghtcd-equip-res:WIDTH = wghtcd-equip-res:WIDTH - 9.
        END.
        IF VALID-HANDLE(wghtcDescEquipe) THEN DO:
            ASSIGN wghtcDescEquipe:ROW = wghtcDescEquipe:ROW - 1
                   wghtcDescEquipe:WIDTH = wghtcDescEquipe:WIDTH - 25
                   wghtcDescEquipe:COLUMN = wghtcd-equip-res:COLUMN + wghtcd-equip-res:WIDTH + 0.5 .
        END.            
        IF VALID-HANDLE(wghtcd-planejado) THEN DO:
            ASSIGN wghtcd-planejado:ROW = wghtcd-planejado:ROW - 1                   
                   wghtcd-planejado:SIDE-LABEL-HANDLE:ROW = wghtcd-planejado:ROW.
        END.

        IF VALID-HANDLE(wghtvData) THEN DO:
            ASSIGN wghtvData:ROW = wghtdt-ini-cedo:ROW
                   wghtvData:COLUMN = wghtvData:COLUMN + 48
                   wghtvData:SIDE-LABEL-HANDLE:ROW = wghtvData:ROW
                   wghtvData:SIDE-LABEL-HANDLE:COLUMN = wghtvData:COLUMN - 12.3
                   wghtvData:SIDE-LABEL-HANDLE:SCREEN-VALUE = "Dt Criação".
        END.
        IF VALID-HANDLE(wghtvHora) THEN DO:
            ASSIGN wghtvHora:ROW = wghtdt-ini-tarde:ROW 
                   wghtvHora:COLUMN = wghtvData:COLUMN
                   wghtvHora:SIDE-LABEL-HANDLE:ROW = wghtvHora:ROW
                   wghtvHora:SIDE-LABEL-HANDLE:COLUMN = wghtvHora:COLUMN - 12.3
                   wghtvHora:SIDE-LABEL-HANDLE:SCREEN-VALUE = "Hr Criação".
        END.
        IF VALID-HANDLE(wghtdt-ini-cedo) THEN DO:
            ASSIGN wghtdt-ini-cedo:COLUMN = wghtdt-ini-cedo:COLUMN - 18.3
                   wghtdt-ini-cedo:SIDE-LABEL-HANDLE:COLUMN = wghtdt-ini-cedo:SIDE-LABEL-HANDLE:COLUMN - 18.3
                   wghtdt-ini-cedo:SIDE-LABEL-HANDLE:SCREEN-VALUE = "Início Cedo".
        END.
        IF VALID-HANDLE(wghtdt-ini-tarde) THEN DO:
            ASSIGN wghtdt-ini-tarde:COLUMN = wghtdt-ini-tarde:COLUMN - 18.3
                   wghtdt-ini-tarde:SIDE-LABEL-HANDLE:COLUMN = wghtdt-ini-tarde:SIDE-LABEL-HANDLE:COLUMN - 18.3
                   wghtdt-ini-tarde:SIDE-LABEL-HANDLE:SCREEN-VALUE = "Início Tarde".
        END.
        CREATE TEXT wgthTxtEquipe2
            ASSIGN FRAME        = wghtcd-equip-res:FRAME
                   FORMAT       = 'x(10)'
                   WIDTH        = 10
                   HEIGHT       = 0.88
                   SCREEN-VALUE = '2ª Equipe:'
                   ROW          = wghtcd-equip-res:ROW 
                   COL          = wghtcd-equip-res:COLUMN + wghtcd-equip-res:WIDTH + wghtcDescEquipe:WIDTH +  3.2
                   VISIBLE      = YES
                   .
        CREATE FILL-IN wghtcDescEquipe2
            ASSIGN FRAME  = wghtcDescEquipe:FRAME
                   WIDTH  = wghtcDescEquipe:WIDTH 
                   HEIGHT = wghtcDescEquipe:HEIGHT
                   ROW    = wghtcDescEquipe:ROW
                   FORMAT = wghtcDescEquipe:FORMAT
                   COLUMN = 64.21                 
                   VISIBLE = TRUE.

        CREATE FILL-IN wghtcd-equip-res2
            ASSIGN FRAME  = wghtcd-equip-res:FRAME
                   WIDTH  = wghtcd-equip-res:WIDTH 
                   HEIGHT = wghtcd-equip-res:HEIGHT
                   ROW    = wghtcd-equip-res:ROW
                   FORMAT = wghtcd-equip-res:FORMAT
                   COLUMN = wghtcd-equip-res:COLUMN + wghtcd-equip-res:WIDTH + wghtcDescEquipe:WIDTH +  11.2
                   VISIBLE = TRUE
                   SENSITIVE = TRUE
            TRIGGERS:
                 ON 'MOUSE-SELECT-DBLCLICK':U  PERSISTENT RUN upc/mi0307a-upc2.p.
            END TRIGGERS.
        
        CREATE TEXT wgthTxtSolicitante
            ASSIGN FRAME        = wghtcd-equip-res:FRAME
                   FORMAT       = 'x(12)'
                   WIDTH        = 13
                   HEIGHT       = 0.88
                   SCREEN-VALUE = 'Solicitante:'
                   ROW          = wghtcd-equip-res:ROW + 1
                   COL          = wghtcd-equip-res:SIDE-LABEL-HANDLE:COLUMN + 8.5
                   VISIBLE      = YES.
        CREATE FILL-IN wgthSolicitante
            ASSIGN FRAME  = wghtcDescEquipe:FRAME
                   WIDTH  = wghtcDescEquipe:WIDTH + 41.7
                   HEIGHT = wghtcDescEquipe:HEIGHT
                   ROW    = wgthTxtSolicitante:ROW
                   COLUMN = wgthTxtSolicitante:COLUMN + wgthTxtSolicitante:WIDTH - 4.8
                   VISIBLE = TRUE
                   FORMAT  = "x(255)"
                   SENSITIVE = YES.
        RUN select-page IN p-wgh-object (INPUT 1).
        
    END.
END.

Rodrigo Rossetto · Dezembro 29, 2010

Também já tive esse problema, o paliativo foi fazer a interação nos eventos do folders.

Rogerio · Dezembro 29, 2010

Cara utilize esse comando.

RUN dispatch IN h-viewer ("initialize":U).
RUN select-page IN p-wgh-object (INPUT 1).

Logar ou Criar uma Conta

[RESOLVIDO] UPC Mudar Folder

kikofr Membro Participativo

Rodrigo Rossetto Membro Participativo

Rogerio Moderator Moderador Equipe de Suporte

Compartilhe esta Página