[RESOLVIDO] Tabelas HCM

Boa tarde,

Alguem tem alguma relação das Tabelas do HCM com a descrição das informações que ela armazena?

Grata!

Olá,

Não conheço nenhum documento que possua estas informações de forma detalhada. Se vc precisa de uma breve descrição pode consultar as propriedades de cada tabela.

Como são muitas eu fiz uma rotina que gera uma lista com os nomes e a descrição de cada tabela. O código segue abaixo:

Abraços.

Trombini

Código:

DEFINE VARIABLE ch-selecao      AS CHARACTER   NO-UNDO.

DEFINE TEMP-TABLE tt-ttbb NO-UNDO
    FIELD nome          AS CHAR FORMAT "x(15)" COLUMN-LABEL "Nome "
    FIELD descricao     AS CHAR FORMAT "x(50)" COLUMN-LABEL "Descrição".

DEFINE FRAME f-banco ch-selecao.

/* UPDATE ch-selecao WITH FRAME f-banco. */

ENABLE ch-selecao WITH FRAME f-banco NO-LABELS TITLE "Digite nome do banco." WIDTH 50.

ON "RETURN":U OF ch-selecao IN FRAME f-banco DO:
    ASSIGN ch-selecao.
    RUN pi-busca-tabelas(INPUT ch-selecao).
    FOR EACH tt-ttbb BY tt-ttbb.nome:
        DISPLAY tt-ttbb.nome
                tt-ttbb.descricao.
    END.
END.

WAIT-FOR WINDOW-CLOSE OF CURRENT-WINDOW.

PROCEDURE pi-busca-tabelas:
    DEFINE INPUT  PARAMETER p-ba1 AS CHARACTER   NO-UNDO.
    DEFINE VARIABLE h-ba1 AS HANDLE      NO-UNDO.
    DEFINE VARIABLE h-ta1 AS HANDLE      NO-UNDO.
    DEFINE VARIABLE h-vcmp AS HANDLE      NO-UNDO.
    DEFINE VARIABLE i-cid AS INTEGER     NO-UNDO.

    CREATE QUERY h-ba1.
    CREATE BUFFER h-ta1 FOR TABLE p-ba1 + "._File".


    h-ba1:ADD-BUFFER(h-ta1).
    h-ba1:QUERY-PREPARE("FOR EACH" + " " +
                             p-ba1 + "._File").
    h-ba1:QUERY-OPEN.
    h-ba1:GET-FIRST().

    EMPTY TEMP-TABLE tt-ttbb.

    DO WHILE NOT h-ba1:QUERY-OFF-END:
        CREATE tt-ttbb.
        REPEAT i-cid = 1 TO h-ta1:NUM-FIELDS:
            ASSIGN h-vcmp = h-ta1:BUFFER-FIELD(i-cid).
            IF h-vcmp:NAME = "_File-Name" THEN
                ASSIGN tt-ttbb.nome = STRING(h-vcmp:BUFFER-VALUE).
            IF h-vcmp:NAME = "_Desc" THEN
                ASSIGN tt-ttbb.descricao = STRING(h-vcmp:BUFFER-VALUE).
        END.
        h-ba1:GET-NEXT().
    END.

    h-ba1:QUERY-CLOSE().
    DELETE OBJECT h-ba1.
END PROCEDURE.

Muito obrigada!