[RESOLVIDO] Programa Template Relatório DDK em RTF

aquele ali é o seu codigo completo ?????

Compara com o seu codigo pra entender o que eu mudei.

Código:

    /* Definiçãoe de Variaveis */
    DEF VAR ch-app-word AS COM-HANDLE NO-UNDO.
    DEF VAR gcDiretorio AS CHAR NO-UNDO.
    DEF VAR cLinha AS CHAR NO-UNDO.
    DEF VAR pcArq AS CHAR NO-UNDO.
    DEF VAR cSeqAux AS CHAR NO-UNDO.
    DEF STREAM sInput.
    DEF STREAM sOutput.


    FOR EACH ri_emb_sobres WHERE ri_emb_sobres.ries_nro = "002/2017" :
   
        ASSIGN pcArq = "Emb_Sobres"
                     + replace(ri_emb_sobres.ries_nro,'/','_')
                     + ".doc"
               gcDiretorio = SEARCH("layout\teste2.rtf").
        INPUT STREAM sInput FROM VALUE(gcDiretorio).
        OUTPUT STREAM sOutput TO VALUE(SESSION:TEMP-DIRECTORY + "/" + pcArq) NO-CONVERT.
        /***************************************************************************/
        /************************ Programa aqui ********************************/
        /***************************************************************************/

        FIND FIRST itens_ri_emb_sobres WHERE itens_ri_emb_sobres.ries_nro = ri_emb_sobres.ries_nro NO-LOCK NO-ERROR.
        IF NOT AVAIL itens_ri_emb_sobres THEN NEXT.
   
        REPEAT:
            IMPORT STREAM sInput UNFORMAT cLinha.
            IF INDEX(cLinha,"#") > 0 THEN DO:
       
                /*** Tabela ri_emb_sobres ****/
                ASSIGN cLinha = REPLACE(cLinha, "#RIES",STRING(ri_emb_sobres.ries_nro))
                cLinha = REPLACE(cLinha, "#DATA",string(ri_emb_sobres.dt-criacao))
                cLinha = REPLACE(cLinha, "#Cliente",string(ri_emb_sobres.nome-cliente))
                cLinha = REPLACE(cLinha, "#SONDA",string(ri_emb_sobres.sonda))
                cLinha = REPLACE(cLinha, "#poco",string(ri_emb_sobres.poco))
                cLinha = REPLACE(cLinha, "#sistema",string(ri_emb_sobres.sistema))
                cLinha = REPLACE(cLinha, "#notafiscal",string(ri_emb_sobres.nota-fiscal))
                cLinha = REPLACE(cLinha, "#transportadora",string(ri_emb_sobres.transportadora))
                cLinha = REPLACE(cLinha, "#placa",string(ri_emb_sobres.placa-veiculo))
                cLinha = REPLACE(cLinha, "#motorista",string(ri_emb_sobres.motorista))
                cLinha = REPLACE(cLinha, "#identidade",string(ri_emb_sobres.identidade))
                cLinha = REPLACE(cLinha, "#rt",string(ri_emb_sobres.rt))
                cLinha = REPLACE(cLinha, "#observacao",string(ri_emb_sobres.observacao)).
       
       
                /*** Tabela itens_ri_emb_sobres ****/
                ASSIGN cLinha = REPLACE(cLinha, "#item",string(itens_ri_emb_sobres.it-codigo))
                cLinha = REPLACE(cLinha, "#ri",string(itens_ri_emb_sobres.ri))
                cLinha = REPLACE(cLinha, "#desc-item",string(itens_ri_emb_sobres.descricao))
                cLinha = REPLACE(cLinha, "#quant",string(itens_ri_emb_sobres.quantidade)).
               
                IF itens_ri_emb_sobres.aprovacao = YES THEN
                    ASSIGN cLinha = REPLACE(cLinha, "#aprov","X")
                           cLinha = REPLACE(cLinha, "#reprov","").
                ELSE
                    ASSIGN cLinha = REPLACE(cLinha, "#reprov","X")
                           cLinha = REPLACE(cLinha, "#aprov","").
            end.
            PUT STREAM sOutput UNFORMATTED cLinha SKIP.
        end.
        PUT STREAM sOutput "~\par }}".
        INPUT STREAM sInput CLOSE.
        OUTPUT STREAM sOutput CLOSE.
        CREATE 'Word.Application':U ch-app-word. /* Cria uma aplica»’o WORD */
        ch-app-word:WindowState = 2. /* O estado dois para o Word ² 2-minimizado */
        ch-app-word:VISIBLE = yes. /* Apenas para n’o mostrar que o word estÿ sendo utilizado em tela */
        ch-app-word:Documents:ADD(SESSION:TEMP-DIRECTORY + "/" + pcArq). /* Inclui arquivo */
        RELEASE OBJECT ch-app-word. /* Elimina o endere»o utilizado para o WORD na mÿquina */
    end.