[RESOLVIDO] Problema ao incluir page no folder

Rogerio · Outubro 28, 2010

Galera, desenvolvi uma UPC para o programa PD1003, para incluir duas abas (page) no folder, mas no momento em que dou o comando RUN create-folder-page in h-folder (INPUT 4, INPUT "NOMEDOFOLDER":U).

o nome da page anterior que era "FISCAL" muda para "Pag. 03"..

ALguem sabe o porque disso?

MFerreira · Novembro 10, 2010

Rogerio,

Você ainda está com esse problema?
Pode disponibilizar a upc (somente a parte de criação dos folders) para analisar?

Att,

Carlão · Novembro 11, 2010

Boa Tarde:

Fiz uma UPC que está funcionando certinho, usando os seguintes comandos:

RUN create-folder-page IN h-folder (INPUT 4, INPUT "NOVO FOLDER":U).
RUN create-folder-label IN h-folder (INPUT 4, INPUT "NOVO FOLDER":U).
RUN select-page IN p-wgh-object (INPUT 4).

Rogerio · Novembro 11, 2010

Segue o codigo do programa que cria as abas

Código:

IF  p-ind-event  = "INITIALIZE"
AND v_nom_objeto = 'pd1003.w'
AND p-ind-object = "CONTAINER" THEN DO:
        RUN get-link-handle IN adm-broker-hdl (INPUT p-wgh-object,
                                               INPUT "PAGE-SOURCE":U,
                                               OUTPUT c-folder).

        MESSAGE 'NKJNL'
            VIEW-AS ALERT-BOX INFO BUTTONS OK.
        ASSIGN h-folder = WIDGET-HANDLE(c-folder) NO-ERROR.
        IF VALID-HANDLE(h-folder) THEN DO:

           /* CRIA A ABA "INF.EXTRAS" */
           RUN create-folder-page IN h-folder  (INPUT 4, INPUT "Inf.Extras":U).
/* AQUI A ABA FISCAL É ALTERADA PARA Pag. 3*/
           RUN create-folder-label IN h-folder (INPUT 4, INPUT "Inf.Extras":U).
           RUN select-page IN p-wgh-object (INPUT 4).
           RUN init-object IN p-wgh-object (INPUT "esupc/pd1003-u02.w":U,
                                            INPUT p-wgh-frame,
                                            INPUT "Layout = ":U,
                                            OUTPUT h-viewer).
           RUN set-position IN h-viewer ( 7.10, 2.5).
           RUN get-link-handle IN adm-broker-hdl (INPUT p-wgh-object,
                                                  INPUT "CONTAINER-TARGET":U,
                                                  OUTPUT c-objects).



           /* CRIA A ABA "Outros" */
           RUN create-folder-page IN h-folder  (INPUT 5, INPUT "Outros":U).
           RUN create-folder-label IN h-folder (INPUT 5, INPUT "Outros":U).
           RUN select-page IN p-wgh-object (INPUT 5).
           RUN init-object IN p-wgh-object (INPUT "esupc/pd1003-u02a.w":U,
                                            INPUT p-wgh-frame,
                                            INPUT "Layout = ":U,
                                            OUTPUT h-viewer2).
           RUN set-position IN h-viewer2 ( 7.10, 2.5).
           RUN get-link-handle IN adm-broker-hdl (INPUT p-wgh-object,
                                                  INPUT "CONTAINER-TARGET":U,
                                                  OUTPUT c-objects).

           /* CRIA SMARTLINKS PARA AS VIEWERS INCLUIDAS */
           DO i-objects = 1 TO NUM-ENTRIES(c-objects):
               ASSIGN h-object = WIDGET-HANDLE(ENTRY(i-objects, c-objects)).

               IF INDEX(h-object:PRIVATE-DATA, "q07in172") <> 0 AND  
               NOT l-record THEN DO:
                   ASSIGN l-record = yes.
                   RUN add-link IN adm-broker-hdl (INPUT h-object, 
                                                   INPUT "Record":U,
                                                   INPUT h-viewer2).
                   RUN add-link IN adm-broker-hdl (INPUT h-object,
                                                   INPUT "Record":U,
                                                   INPUT h-viewer).
               END.
               IF INDEX(h-object:PRIVATE-DATA, "v01in172") <> 0 AND 
               NOT l-group-assign THEN DO:
                   ASSIGN l-group-assign = YES.
                   RUN add-link IN adm-broker-hdl (INPUT h-object, 
                                                   INPUT "Group-Assign":U,
                                                   INPUT h-viewer2).
                   RUN add-link IN adm-broker-hdl (INPUT h-object,
                                                   INPUT "Group-Assign":U,
                                                   INPUT h-viewer).
               END.

           END.
           
           RUN dispatch IN h-viewer  ("initialize":U).
           RUN dispatch IN h-viewer2 ("initialize":U).
           RUN select-page IN p-wgh-object (INPUT 4).
           RUN select-page IN p-wgh-object (INPUT 1).
        END. 
END.

eduardo.leite · Novembro 17, 2010

Rogério,

Verifiquei o código e está tudo certo, a rotina PD1003 deve estar ocorrendo algum problema na geração de novos folder, entrando em contradição.

Fiz alguns testes aqui na minha base e consegui renomear a pasta "Pag.03" para "Fiscal" no final da UPC, só que tive que renomear alguns chamadas das viewer pois não as tinha aqui, copie o código abaixo e faça um teste em sua base:

Código:

if  p-ind-event  = "INITIALIZE"     and
    v_nom_objeto = 'pd1003.w'       and
    p-ind-object = "CONTAINER"      then do:

    run get-link-handle in adm-broker-hdl (input  p-wgh-object,
                                           input  "PAGE-SOURCE":U,
                                           output c-folder).

    assign h-folder = widget-handle(c-folder) no-error.

    if valid-handle(h-folder) then do:

        run create-folder-page  in h-folder (input 4, input "Inf.Extras":U).
        run create-folder-label in h-folder (input 4, input "Inf.Extras":U).


       run select-page in p-wgh-object (input 4).
       
       run init-object in p-wgh-object (input  "esupc/pd1003-u02.w":U,
                                        input  p-wgh-frame,
                                        input  "Layout = ":U,
                                        output h-viewer).

       run set-position in h-viewer ( 7.10, 2.5).

       run get-link-handle in adm-broker-hdl (input  p-wgh-object,
                                              input  "CONTAINER-TARGET":U,
                                              output c-objects).

       run create-folder-page   in h-folder     (input 5, input "Outros":U).
       run create-folder-label  in h-folder     (input 5, input "Outros":U).

       run select-page          in p-wgh-object (input 5).

       run init-object          in p-wgh-object (input  "esupc/pd1003-u02a.w":U,
                                                 input  p-wgh-frame,
                                                 input  "Layout = ":U,
                                                 output h-viewer2).

       run set-position     in h-viewer2 ( 7.10, 2.5).
       
       run get-link-handle  in adm-broker-hdl (input  p-wgh-object,
                                               input  "CONTAINER-TARGET":U,
                                               output c-objects).

       do i-objects = 1 to num-entries(c-objects):

           assign h-object = widget-handle(entry(i-objects, c-objects)).

           if index(h-object:private-data, "q07in172") <> 0 and
              not l-record                                  then do:

               assign l-record = yes.

               run add-link in adm-broker-hdl (input h-object,
                                               input "Record":U,
                                               input h-viewer2).

               run add-link in adm-broker-hdl (input h-object,
                                               INPUT "Record":U,
                                               input h-viewer).

           end.

           if index(h-object:private-data, "v01in172") <> 0 and
              not l-group-assign                            then do:

               assign l-group-assign = yes.

               run add-link in adm-broker-hdl (input h-object,
                                               input "Group-Assign":U,
                                               input h-viewer2).

               run add-link in adm-broker-hdl (input h-object,
                                               input "Group-Assign":U,
                                               input h-viewer).

           end.

       end.
       
       /***** Alterado aqui por Eduardo Leite - Renomeado a Pasta 03 - Fiscal *****/
       run create-folder-label in h-folder (input 3, input "Fiscal":U).

       run dispatch in h-viewer  ("initialize":U).
       run dispatch in h-viewer2 ("initialize":U).

       run select-page in p-wgh-object (input 5).
       run select-page in p-wgh-object (input 4).
       run select-page in p-wgh-object (input 3).
       run select-page in p-wgh-object (input 2).
       run select-page in p-wgh-object (input 1).

    end. 

end.

Logar ou Criar uma Conta

[RESOLVIDO] Problema ao incluir page no folder

Rogerio Moderator Moderador Equipe de Suporte

MFerreira Membro Participativo

Carlão Sem Pontuação

Rogerio Moderator Moderador Equipe de Suporte

eduardo.leite Equipe de Suporte Moderador Equipe de Suporte

Compartilhe esta Página