Ler nome de Arquivos dentro de uma Pasta

Olá galera!
Alguém sabe como fazer para ler o nome dos arquivos dentro de uma determinada pasta?
É q na verdade eu preciso o seguinte, tenho um cliente que tem umas 5.000 fotos de pacientes, e desenvolvi um programa em progress para a clinica dele, agora ele quer que eu separe as fotos por pasta, e cada pasta para um paciente, para criar as pastas com o nome do paciente automaticamente já sei como fazer, só falta ler o nome de cada foto para copia para a pasta correta. As fotos estão gravadas com o código do paciente, Exemplo: 0000125-1.jpg, 0000125-2.jpg, etc...

Att,

Diogo

Bom dia..

cara aqui tenho um ex. com um browser, usando tt...

Código:

INPUT FROM OS-DIR (diretorio:SCREEN-VALUE IN FRAME f-cad) CONVERT SOURCE "iso8859-1".
    REPEAT:
            CREATE tt-arquivos.
            IMPORT tt-arquivos.arquivo.
    END.
    INPUT CLOSE.
    FOR EACH tt-arquivos:
        IF NOT tt-arquivos.arquivo MATCHES "*.txt" THEN DO:
            DELETE tt-arquivos.
        END.
    END.

eu pego todos os arquivos .txt de algum diretório e mostro no browser...

Código:

def var vArq as char extent 3.

input from os-dir("C:\Fotos").
   repeat:
      import vArq.
      message
         "Nome:" vArq[1] skip
         "Path:" vArq[2] skip
         "Tipo:" vArq[3] skip
         view-as alert-box.
   end.
input close.

Ótimo! Deu certo, muito obrigado!

Att,

Diogo

Resgatando o tópico que acaba de me ajudar.
Só fiz alguns complementos e estou colocando se alguém tiver interesse:

Código:

/*--- temp table de arquivos com todas as informações que vou precisar ---*/
DEF TEMP-TABLE tt-arquivos
    FIELD nome AS CHAR FORMAT "x(50)"
    FIELD caminho AS CHAR FORMAT "x(50)"
    FIELD tipo AS CHAR FORMAT "x(4)"
    FIELD criacao AS DATE
    FIELD modificacao AS DATE
    FIELD tamanho AS DEC FORMAT "->>>,>>>,>>>,>>>,>>9.99".

INPUT FROM OS-DIR ("c:\temp") CONVERT SOURCE "iso8859-1".
REPEAT:
        CREATE tt-arquivos.
        /*--- importando as informações básicas do arquivo,
              que são nome, caminho e tipo ---*/
        IMPORT tt-arquivos.
        /*--- apontando para o arquivo que importei e definindo
              as informações adicionais que preciso ---*/
        ASSIGN FILE-INFO:FILE-NAME = tt-arquivos.caminho.
        ASSIGN tt-arquivos.criacao = DATE(FILE-INFO:FILE-CREATE-DATE).
        ASSIGN tt-arquivos.modificacao = DATE(FILE-INFO:FILE-MOD-DATE).
        ASSIGN tt-arquivos.tamanho = FILE-INFO:FILE-SIZE.

END.
INPUT CLOSE.