[RESOLVIDO] FT0910

bom dia.

Pessoal, vocês por acaso conhecem alguma "BO" que faça o que o ft0910 faz?

Tenho um desenvolvimento em caracter para gerar nota fiscal. Este desenvolvimento gera a nota fiscal sem problemas, mas não manda para o sefaz, ou seja, não gera o xml. Se existir uma bo ou se eu puder passar parâmetros para o ft0910 resolveria o meu problema. Alguém conhce alguma coisa sobre este assunto?
Toda da a vez que gero um nota fiscal, tenho que entrar no ft0910 e mandar anota fiscal para o sefaz.

Obrigado

Segue uma upc no bodi317ef.p:

PHP:

/*******************************************************************************
**  Programa : epc_bodi317ef                                                        
**  Objetivo : Converte Arquivo TXT do SEFAZ para XML
                                                
*******************************************************************************/
{include/i-epc200.i bodi317ef}
/* Parametros ---*/
define input  parameter p-ind-event as character  no-undo.
define input-output parameter table for tt-epc.

/* Temp-Table Notas Geradas ---*/
def temp-table tt-notas-geradas no-undo
  field rw-nota-fiscal as  rowid
  field nr-nota        like nota-fiscal.nr-nota-fis
  field seq-wt-docto  like wt-docto.seq-wt-docto.

/* Defini‡Æo de Temp-Table ---*/
define temp-table tt-param
    field destino as int
    field arquivo as char
    field usuario as char
    field data-exec as date
    field hora-exec as integer
    field cod-estabel as char
    field serie as char
    field nr-nota-fis-ini as char
    field nr-nota-fis-fim as char
    field nome-ab-cli-ini as char
    field nome-ab-cli-fim as char
    field dt-emis-nota-ini as date
    field dt-emis-nota-fim as date
    field gera-nfe-n-gerada as log
    field gera-nfe-gerada as log
    field exporta-est-txt as log
    field gera-nfe-cancel as log
    field gera-nfe-inut as log
    field c-motivo as char.

define temp-table tt-raw-digita
  field raw-digita as raw.

/* Definicao Variaveis Globais ---*/
define new global shared variable h-bodi317ef          as handle    no-undo.
define new global shared variable r-wt-docto            as rowid      no-undo.

/* Definicacao Variaveis Locais ---*/
define variable h-eceapi001        as handle    no-undo.
define variable l-procedimento      as logical    no-undo.
define variable v-raw-param        as raw        no-undo.

/* Inicio ---*/
for each tt-epc where tt-epc.cod-event = p-ind-event:

  /* AfterEfetivaNota ---*/
  if tt-epc.cod-event    = "EndEfetivaNota2" and
    tt-epc.cod-parameter = "object-handle"    then
  do:

    assign h-bodi317ef = widget-handle(tt-epc.val-parameter).

    run buscaTTNotasGeradas in h-bodi317ef(output l-procedimento,
      output table tt-notas-geradas).
    if l-procedimento then
    do:
      /* Notas Geradas ---*/
      for each tt-notas-geradas no-lock:
        for each nota-fiscal fields( cod-estabel serie nr-nota-fis)
            where rowid(nota-fiscal)    = tt-notas-geradas.rw-nota-fiscal  no-lock:
            run pi-processa in this-procedure.
        end. /* nota-fiscal ---*/
      end. /* tt-notas-geradas ---*/
    end. /* l-procedimento ---*/
  end. /* AfterEfetivaNota ---*/
end. /* tt-epc ---*/
/* Fim ---*/

/* Procedures ---*/
procedure pi-processa.

    find estabelec where estabelec.cod-estabel = nota-fiscal.cod-estabel no-lock no-error.
    if avail estabelec then do:
      if trim(substring(estabelec.char-1,183,256)) ne "" then do:
          find ser-estab where ser-estab.cod-estabel = nota-fiscal.cod-estabel
                            and ser-estab.serie = nota-fiscal.serie no-lock no-error.
          if avail ser-estab then do:
              if substring(ser-estab.char-1,1,3) = "yes" then do:
                create  tt-param.
                assign  tt-param.destino = 3
                        tt-param.arquivo = session:temp-dir + "ft0910.txt"
                        tt-param.usuario = "super"
                        tt-param.data-exec = today
                        tt-param.cod-estabel = nota-fiscal.cod-estabel
                        tt-param.serie = nota-fiscal.serie
                        tt-param.nr-nota-fis-ini = nota-fiscal.nr-nota-fis
                        tt-param.nr-nota-fis-fim = nota-fiscal.nr-nota-fis
                        tt-param.nome-ab-cli-ini = ""
                        tt-param.nome-ab-cli-fim = "ZZZZZZZZZZZZ"
                        tt-param.dt-emis-nota-ini = 01/01/2001
                        tt-param.dt-emis-nota-fim = 12/31/9999
                        tt-param.gera-nfe-n-gerada = yes
                        tt-param.gera-nfe-gerada = yes
                        tt-param.exporta-est-txt = no
                        tt-param.gera-nfe-cancel = no
                        tt-param.gera-nfe-inut = no
                        tt-param.c-motivo = "".
                    
                raw-transfer tt-param to v-raw-param.
            
                run ftp/ft0910rp.p (input v-raw-param,
                                    input table tt-raw-digita).
                              
              end.
          end.
        end.
    end.
end procedure.                
/* Fim ---*/