[RESOLVIDO] Inclusão de Campo CD0903

Prezados, boa noite. Gostaria de saber se alguém consegue me ajudar com a duvida que estou tendo. Preciso incluir um novo campo no Programa CD0903, primeira aba, Inf Gerais. Não estou conseguindo pegar a Frame(Ex: 1, 2,3,4 ou 5) dessa página, alguém tem um exemplo? Muito Obrigado.

Rodrigo segue um exemplo simples que adiciona um campo abaixo do campo Unidade de negócio. Depois você pode melhorá-lo.

Código:

{include/fc-handle-obj.i}

DEFINE INPUT PARAMETER p-ind-event              AS CHAR          NO-UNDO.
DEFINE INPUT PARAMETER p-ind-object             AS CHAR          NO-UNDO.
DEFINE INPUT PARAMETER p-wgh-object             AS HANDLE        NO-UNDO.
DEFINE INPUT PARAMETER p-wgh-frame              AS WIDGET-HANDLE NO-UNDO.
DEFINE INPUT PARAMETER p-cod-table              AS CHAR          NO-UNDO.
DEFINE INPUT PARAMETER p-row-table              AS ROWID         NO-UNDO. 

DEFINE VARIABLE c-handle-obj  AS CHARACTER     NO-UNDO.

DEFINE NEW GLOBAL SHARED VAR wh-cd0903-cod-unid-negoc      AS WIDGET-HANDLE NO-UNDO.
DEFINE NEW GLOBAL SHARED VAR wh-cd0903-lbl-campo-adicional AS WIDGET-HANDLE NO-UNDO.
DEFINE NEW GLOBAL SHARED VAR wh-cd0903-campo-adicional     AS WIDGET-HANDLE NO-UNDO.

IF p-ind-event            = "BEFORE-INITIALIZE" AND
   p-ind-object           = "VIEWER" AND
   p-wgh-object:FILE-NAME = "invwr/v42in172.w" THEN
DO:
   ASSIGN c-handle-obj = fc-handle-obj("c-cod-unid-negoc", p-wgh-frame).      
   ASSIGN wh-cd0903-cod-unid-negoc = WIDGET-HANDLE(ENTRY(1, c-handle-obj)) NO-ERROR.

   CREATE TEXT wh-cd0903-lbl-campo-adicional
      ASSIGN FRAME      = wh-cd0903-cod-unid-negoc:FRAME
             NAME       = 'lbl-campo-adicional'
             FORMAT     = "x(16)"
             TOOLTIP    = "?"
             COL        = wh-cd0903-cod-unid-negoc:COL - 12
             ROW        = wh-cd0903-cod-unid-negoc:ROW + 1 + 0.1
             WIDTH      = 16
             VISIBLE    = YES.
      wh-cd0903-lbl-campo-adicional:SCREEN-VALUE = 'Campo Adicional:'.

      CREATE FILL-IN wh-cd0903-campo-adicional
      ASSIGN FRAME             = wh-cd0903-cod-unid-negoc:FRAME
             SIDE-LABEL-HANDLE = wh-cd0903-lbl-campo-adicional
             DATA-TYPE         = "INTEGER"
             FORMAT            = ">,>>>,>>9"
             NAME              = 'campo-adicional'
             HELP              = "Campo adicional"
             TOOLTIP           = "Campo adicional"
             COL               = wh-cd0903-cod-unid-negoc:COL
             ROW               = wh-cd0903-cod-unid-negoc:ROW + 1
             WIDTH             = 12
             HEIGHT            = 0.88
             SENSITIVE         = NO
             VISIBLE           = YES
         TRIGGERS:
            ON "LEAVE":U PERSISTENT RUN upc/upccd0903-u01.p(INPUT "LEAVE"                   ,
                                                            INPUT "wh-cd0903-campo-adicional",
                                                            INPUT ?                         ,
                                                            INPUT ?                         ,   
                                                            INPUT ?                         ,
                                                            INPUT ?                          ).
   
            ON "MOUSE-SELECT-DBLCLICK":U, "F5":U PERSISTENT RUN upc/upccd0903-u01.p (INPUT "ZOOM"                    ,
                                                                                     INPUT "wh-cd0903-campo-adicional",
                                                                                     INPUT ?                         ,
                                                                                     INPUT ?                         ,   
                                                                                     INPUT ?                         ,
                                                                                     INPUT ?                          ).
         END TRIGGERS.

END.


IF p-ind-event            = "AFTER-ENABLE" AND
   p-ind-object           = "VIEWER" AND
   p-wgh-object:FILE-NAME = "invwr/v42in172.w" THEN
DO:
   IF VALID-HANDLE(wh-cd0903-campo-adicional) THEN
   DO:
      wh-cd0903-campo-adicional:SENSITIVE = YES.
   END.
END.

IF p-ind-event            = "AFTER-DISABLE" AND
   p-ind-object           = "VIEWER" AND
   p-wgh-object:FILE-NAME = "invwr/v42in172.w" THEN
DO:
   IF VALID-HANDLE(wh-cd0903-campo-adicional) THEN
   DO:
      wh-cd0903-campo-adicional:SENSITIVE = NO.
   END.
END.


IF p-ind-event  = "LEAVE" AND
   p-ind-object = "wh-cd0903-campo-adicional" THEN
DO:
   IF VALID-HANDLE(wh-cd0903-campo-adicional) THEN
   DO:
      MESSAGE "LEAVE"
         VIEW-AS ALERT-BOX INFO BUTTONS OK.
   END.
END.

IF p-ind-event  = "ZOOM" AND
   p-ind-object = "wh-cd0903-campo-adicional" THEN
DO:
   IF VALID-HANDLE(wh-cd0903-campo-adicional) THEN
   DO:
      MESSAGE "ZOOM"
         VIEW-AS ALERT-BOX INFO BUTTONS OK.
   END.
END.

Muito obrigado pela atenção "ecosta". Uma outra duvida que gostaria de tirar, como eu faço para pegar o código do item que está sendo apresentado no programa CD0903?

Tentei dessa forma e não me traz o resultado:

RUN utils/findWidget(INPUT 'it-codigo':u,
INPUT 'FILL-IN:u,
INPUT p-wgh-frame,
OUTPUT vhdItCodigo).

Obrigado!!!

Rodrigo, você pode adicionar o código abaixo no programa anterior. Ele pega a handle do campo Item da view principal.

Código:

DEFINE NEW GLOBAL SHARED VAR wh-cd0903-it-codigo      AS WIDGET-HANDLE NO-UNDO.

IF p-ind-event            = "BEFORE-INITIALIZE" AND
   p-ind-object           = "VIEWER" AND
   p-wgh-object:FILE-NAME = "invwr/v41in172.w" THEN
DO:
   ASSIGN c-handle-obj = fc-handle-obj("it-codigo", p-wgh-frame).      
   ASSIGN wh-cd0903-it-codigo = WIDGET-HANDLE(ENTRY(1, c-handle-obj)) NO-ERROR.
END.

Bom dia, ecosta,

Será que voce consegue me passar esta include
{include/fc-handle-obj.i}

No aguardo

Me mande seu e-mail.